Flash AS3.0教程：含有多个类的AS3类文件

文章来源于中国教程网论坛，感谢作者 cao4811 给我们带来经精彩的文章！

设计教程/设计教程/Flash教程2009-09-01

AS3.0 含有多个类的AS3类文件标准的AS3类文件是以.as为结尾的纯文本文件。一个类文件可以包含一个或多个类定义，甚至可以直接写入一次性执行的语句。AS3中，在package花括号外，可以定义一个或多个Class，不可与文件同名。这些花括号外的类，称为当前类文件

AS3.0 含有多个类的AS3类文件

标准的AS3类文件是以".as"为结尾的纯文本文件。一个类文件可以包含一个或多个类定义，甚至可以直接写入一次性执行的语句。AS3中，在package花括号外，可以定义一个或多个Class，不可与文件同名。这些花括号外的类，称为当前类文件的包外类。只有当前类文件中的成员可以访问。

包外类的产生，每个.as文件被编译器看成一个编译单元，每个编译单元只能有一个对外可见的Class, 那么package{}之外的Class就对外不可见了。

为什么需要包外类？

第一，我们可以将包外类看成当前文件的“私有类”，。比如，可以将当前类中的一些复杂逻辑单独抽出来做成类，如果这些抽出来的逻辑只和这个当前类相关，不需要外部介入，那么就可将这些类定义成包外类。

第二，由于包外类对外部完全不可见，在AS3中有它特有的用处，比如，AS3不支持private和protected的构造函数，要想真正实现单例模式（Singleton)，就可以用上包外类了。

基本结构如下：

package {
     class MyClass {
         function MyClass() {
             var helper:MyHelper = new MyHelper();
         }
     }
}
class MyHelper {
     function MyHelper() {
         var helper:HelpersHelper = new HelpersHelper();
     }
}
class HelpersHelper {
     function HelpersHelper () {
     }
}

注意：在包块中最多只能定义一个类。在同一个文件中的辅助类不是包块的一部分，并且只能在此文件中可见和被使用。

下面我们将我们将我们的类改写成上述的packge类形式。我们将下面的代码都写在一个DocumentClass.as的文件中，然后在fla文件中的属性面板中的Document Class输入框中输入DocumentClass类名。

package {
        import flash.display.MovieClip;
        import flash.display.Sprite;
        import flash.events.MouseEvent;
        // Document Class
        public class DocumentClass extends MovieClip {
                private var _circle:Drag_circle;
                private const maxBalls:int=100;
                public function DocumentClass() {
                        var i:int;
                        for (i=0; i <= maxBalls; i++) {
                                _circle=new Drag_circle ;
                                _circle.scaleY=_circle.scaleX=Math.random();
                                _circle.x=Math.round(Math.random() * stage.stageWidth -

_circle.width);
_circle.y=Math.round(Math.random() * stage.stageHeight -

_circle.height);
                                addChild(_circle);
                        }
                }
        }
}
import flash.display.Sprite;
import flash.events.MouseEvent;
class Drag_circle extends Sprite {
        private var _circle:Sprite;
        public function Drag_circle() {
                _circle=new Sprite ;
                _circle.graphics.beginFill(0xff0000);
                _circle.graphics.drawCircle(-5,-5,10);
                _circle.graphics.endFill();
                addChild(_circle);
                this.buttonMode=true;
                _circle.addEventListener(MouseEvent.CLICK,onClick);
                _circle.addEventListener(MouseEvent.MOUSE_DOWN,onDown);
                _circle.addEventListener(MouseEvent.MOUSE_UP,onUp);
        }
        private function onClick(event:MouseEvent):void {
                trace("circle clicked");
        }
        private function onDown(event:MouseEvent):void {
                _circle.startDrag();
        }
        private function onUp(event:MouseEvent):void {
                _circle.stopDrag();
        }
}

可以测试你的影片了。

进入论坛参与评论: http://www.missyuan.com/viewthread.php?tid=417560

情非得已